JavaFX no Carnaval

Obrigado a todos que compareceram a meu webinar de JavaFX mesmo durante o carnaval. =)

Conforme prometido aqui estão os slides que nós utilizamos:

Download: javafx_carnaval2009.odp

Para assistir o replay da apresentação, clique aqui.

Nos exemplos de código eu procurei seguir a abordagem do Robert Eckstein no videocast Learn JavaFX Script in 15 minutes. O resultado foi muito bom para apresentar a sintáxe da linguagem.

Exemplo 1

def raio = 4;
def Pi = 3.1415;
 
var area = Pi * (raio * raio);
 
println("Área do círculo: {area}");

Saída do Exemplo 1:

Área do círculo: 50.264

Exemplo 2

var isActive = true;
var isVisible:Boolean = false;
 
println("Active: {isActive}");
println("Visible: {isVisible}");
 
isVisible = true;
 
println("Visible: {isVisible}");

Saída do Exemplo 2:

Active: true
Visible: false
Visible: true

Exemplo 3

var integer1 = 3;
var number1 = 3.0;
 
var integer2:Integer = 3;
var number2:Number = 3.0;
var number3:Number = integer1;
 
println("Integer 1: {integer1}");
println("Integer 2: {integer2}");
 
println("Number 1: {number1}");
println("Number 2: {number2}");
println("Number 3 (copiado do integer 3): {number3}");
 
println("Number 1 como Integer: {number1 as Integer}");

Saída do Exemplo 3:

Integer 1: 3
Integer 2: 3
Number 1: 3.0
Number 2: 3.0
Number 3 (copiado do integer 3): 3.0
Number 1 como Integer: 3

Exemplo 4

var s1 = "Olá";
var s2:String = "Olá";
 
var s3 = "Olá 'mundo'";
var s4 = 'Olá "mundo" ';
 
println("Primeira String é {s1}");
println("Segunda String é {s2}");
println("Terceira String é {s3}");
println("Quarta String é {s4}");

Saída do Exemplo 4:

Primeira String é Olá
Segunda String é Olá
Terceira String é Olá ‘mundo’
Quarta String é Olá “mundo”

Exemplo 5

var hora = 16;
println("Olá! {if(hora < 12) "Bom dia" else "Boa tarde"}");
 
def string1 = "Java";
def string2 = "FX";
def javafxstring = "{string1}{string2}";
println(javafxstring);

Saída do Exemplo 5:

Olá! Boa tarde
JavaFX

Exemplo 6

var duration1 = 1s;
var duration2 = 10m;
var duration3:Duration = 5h;
var duration4:Duration = 1ms;
 
println("Duração 1 é (5 seg): {duration1}");
println("Duração 2 é (10 min): {duration2}");
println("Duração 3 é (5 h): {duration3}");
println("Duração 4 é (1 milisegundo): {duration4}");
println("Duração 1 + Duração 2 (10min e 5 seg): {duration1+duration2}");

Saída do Exemplo 6:

Duração 1 é (5 seg): 1000ms
Duração 2 é (10 min): 600000ms
Duração 3 é (5 h): 18000000ms
Duração 4 é (1 milisegundo): 1ms
Duração 1 + Duração 2 (10min e 5 seg): 601000ms

Exemplo 7

def Pi = 3.1415;
def raio = 5;
 
println("A área do círculo é {getArea(raio)}");
 
function getArea(raio: Number): Number {
    var area = Pi * (raio*raio);
    return area;
}

Saída do Exemplo 7:

A área do círculo é 78.53750000000001

Exemplo 8

function checaBalanço(cta:Conta):Void{
    if(cta==null){
        println("Conta nula");
    }else{
        println("Balanço é de {cta.balanço}");
    }
}
 
class Conta {
    var balanço: Number;
}
 
var minhaconta = Conta {
    balanço: 9.99
}
 
checaBalanço(minhaconta);

Saída do Exemplo 8:

Balanço é de 9.99

Exemplo 9

class Monstro {
    var nome: String;
    var nível: Integer;
    var vida: Number;
}
 
var ogr = Monstro {
    nome: "Ogro"
    nível: 16;
    vida: 100.0;
}
 
println("nome: {ogr.nome}");
println("nível: {ogr.nível}");
println("vida: {ogr.vida}");

Saída do Exemplo 9:

nome: Ogro
nível: 16
vida: 100.0

Exemplo 10

class Monstro {
    var nome: String;
    var nível: Integer;
    var vida: Number;
    var força: Number;
 
    function porrada(outro:Monstro){
        outro.vida = outro.vida - força;
    }
}

Exemplo 11

abstract class MonstroVoador {
    var nome: String = "monstro voador";
    abstract function voa():Void;
}
 
class Griffon extends MonstroVoador{
    override function voa(){
        println("estou voando =D");
    }
}

Exemplo 12

var software: String[] = ["NetBeans", "Java", "JavaFX"];
var hardware: String[] = ["UltraSparc", "Niagra", "SunSpot"];
 
var oferta = [software,hardware];
 
println(software);
println(hardware);
println(oferta);

Saída do Exemplo 12:

[ NetBeans, Java, JavaFX ]
[ UltraSparc, Niagra, SunSpot ]
[ NetBeans, Java, JavaFX, UltraSparc, Niagra, SunSpot ]

Exemplo 13

var A = [1..10];
var B = [1,2,3,4,5,6,7,8,9,10];
 
println("A é igual a B? {A==B}");
 
var C: Integer[] = [1..11];
 
println("A é igual a C? {A==C}");

Saída do Exemplo 13:

A é igual a B? true
A é igual a C? false

Exemplo 14

var umadez = [1..10];
var copia = umadez;
 
println(umadez);
println(copia);
 
var outracopia = umadez[valor|true];
println(outracopia);
 
var sopares = umadez[valor|(valor mod 2)==0];
println(sopares);

Saída do Exemplo 14:

[ 1, 2, 3, 4, 5, 6, 7, 8, 9, 10 ]
[ 1, 2, 3, 4, 5, 6, 7, 8, 9, 10 ]
[ 2, 4, 6, 8, 10 ]

Exemplo 15

var sequencia = [1..10];
 
println("tamanho de sequencia é {sizeof sequencia}");
 
insert 11 into sequencia;
delete 3 from sequencia;
insert 3 before sequencia[2];
delete sequencia[1];
insert 2 after sequencia[0];
println(sequencia);
 
delete sequencia;
println(sequencia);

Saída do Exemplo 15:

tamanho de sequencia é 10
[ 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11 ]
[ ]

Exemplo 16

var meses = ["jan", "fev", "mar", "abr", "mai", "jun", "jul",
             "ago", "set", "out", "nov", "dez"];
 
println(sizeof meses);
println(meses[2..5]);
println(meses[2..<5]);
println(meses[2..]);
println(meses[2..<]);

Saída do Exemplo 16:

12
[ mar, abr, mai, jun ]
[ mar, abr, mai ]
[ mar, abr, mai, jun, jul, ago, set, out, nov, dez ]
[ mar, abr, mai, jun, jul, ago, set, out, nov ]

Exemplo 17

var meses = ["jan", "fev", "mar", "abr", "mai", "jun", "jul",
             "ago", "set", "out", "nov", "dez"];
 
for(mes in meses){
    println(mes);
}

Saída do Exemplo 17:

jan
fev
mar
abr
mai
jun
jul
ago
set
out
nov
dez

silveira neto

carbon-based lifeform. virgo supercluster